Skapa PDF

Skapar en tom PDF-fil i minnet. Lägg till sidor med scriptsteg som Lägg till i PDF, stäng och spara sedan filen med scriptsteget Stäng PDF.

Se även 

Tillval 

  • Ange alternativ visar dialogrutan PDF-alternativ. När det här alternativet är markerat anger Återställ att PDF-alternativ lagras i scriptsteget.

    • På fliken Dokument kan du ange beskrivande information för PDF-filen. För varje alternativ på dokumentfliken kan du ange text direkt, eller klicka på Ange om du vill ange ett fältnamn eller värde från en beräkning.

    • På fliken Säkerhet kan du tilldela lösenord till PDF-filen, liksom utskrifts- och redigeringsbehörighet. Om behörighet för utskrift och redigering medges kan du ange om programvara för kopiering och skärmläsning är tillåtet.

    • På fliken Startvy kan du definiera startvyn för layouten och förstoringsgraden för PDF-filen.

Kompatibilitet 

Produkt Stöds
FileMaker Pro Ja
FileMaker Go Ja
FileMaker WebDirect Ja
FileMaker Server Ja
FileMaker Cloud Ja
FileMaker Data API Ja
Anpassad webbpublicering Ja

Ursprungsversion 

26.0

Beskrivning 

Det här scriptsteget skapar en ny, tom PDF-fil i minnet som du sedan kan ändra med andra scriptsteg för PDF-filer. PDF-filen öppnas och förblir öppen tills du stänger den med Scriptsteget Stäng PDF eller Scriptsteget Avbryt PDF.

När en PDF-fil är öppen kan du:

Det här arbetsflödet är användbart när du vill skapa komplexa PDF-dokument som kombinerar sidor från flera källor, till exempel ett försättsblad, rapportdata och bilagor, allt samlat i en och samma PDF-fil.

Kommentarer 

  • Endast en PDF-fil kan vara öppen åt gången. Om en PDF-fil redan är öppen returnerar det här scriptsteget felkod 833 ("PDF-filen är redan öppen").

  • Den skapade PDF-filen finns bara i minnet tills du sparar den med Scriptsteget Stäng PDF.

  • Den öppna PDF-filen och eventuella ändringar som inte sparats går förlorade om något av följande inträffar:

    • Den aktuella FileMaker-klientsessionen avslutas.

    • FileMaker Pro-filen vars script öppnade PDF-filen stängs utan att den öppna PDF-filen först stängs.

Exempel 1 - Skapa ett enkelt PDF-dokument

Skapar en PDF-fil, lägger till sidor för de poster som för närvarande bearbetas och sparar den i mappen Dokument.

Kopiera 
Skapa PDF [ ]

Gå till layout [ "Kontakter" (Kontakter) ; Animering: Ingen ]

Spara poster i PDF-format [ Återställ ; Spara i: Nu öppen PDF ; Alla poster som bearbetas ]

Ange variabel [ $pdfFilSökväg ; Värde: Get ( Dokumentsökväg ) & "Rapport.pdf" ]

Stäng PDF [ Spara i: Fil ; $pdfFilSökväg ; Skapa mappar: Av ]

Exempel 2 - Skapa en PDF-rapport av flera avsnitt

Skapar en krypterad PDF-rapport genom att kombinera ett försättsblad, flera dataavsnitt och en sammanfattningssida. Skapa PDF använder Ange alternativ för att ange ett lösenord för att öppna filen.

Kopiera 
Skapa PDF [ Återställ ]

Lägg till i PDF [ Källa: Fil ; "Försättsblad.pdf" ]

Gå till layout [ "Beställningar" (Beställningar) ]
Spara poster i PDF-format [ Återställ ; Spara i: Nu öppen PDF ; Alla poster som bearbetas ]

Gå till layout [ "Kunder" (Kunder) ]
Spara poster i PDF-format [ Återställ ; Spara i: Nu öppen PDF ; Alla poster som bearbetas ]

Lägg till i PDF [ Från: Källa ; Global::Sammanfattningssida ]

Ange variabel [ $pdfFilSökväg ; Värde: Get ( Dokumentsökväg ) & "Fullständig_rapport_" & Year ( Get ( AktuelltDatum ) ) & ".pdf" ]

Stäng PDF [ Spara i: Fil ; $pdfFilSökväg ; Skapa mappar: Av ]

Exempel 3 - Skapa PDF med felhantering

Skapar en PDF-rapport med felhantering för att säkerställa att PDF-filen stängs om ett fel uppstår. Observera att efter ett misslyckat försök att ändra PDF-filen stängs PDF-filen utan att sparas med Scriptsteget Avbryt PDF.

Kopiera 
Manuell felhantering [ På]

Skapa PDF [ ]
Ange variabel [ $felkod ; Värde: Get ( SenasteFel ) ]
If [ $felkod ≠ 0 ]
    Visa anpassad dialogruta [ "Fel" ; "Det gick inte att skapa PDF-filen: " & $felkod ]
    Avsluta script [ Textresultat: "Misslyckades" ]
End If

Lägg till i PDF [ Från: Fil ; "Försättsblad.pdf ]
Ange variabel [ $felkod ; Värde: Get ( SenasteFel ) ]
If [ $felkod ≠ 0 ]
    Avbryt PDF
    Visa anpassad dialogruta [ "Fel" ; "Det gick inte att lägga till försättsbladet: " & $felkod ]
    Avsluta script [ Textresultat: "Misslyckades" ]
End If

Spara poster i PDF-format [ Återställ ; Spara i: Nu öppen PDF ; Alla poster som bearbetas ]
Ange variabel [ $felkod ; Värde: Get ( SenasteFel ) ]
If [ $felkod ≠ 0 ]
    Avbryt PDF
    Visa anpassad dialogruta [ "Fel" ; "Det gick inte att lägga till posterna: " & $felkod ]
    Avsluta script [ Textresultat: "Misslyckades" ]
End If

Stäng PDF [ Spara i: Fil ; "Rapport.pdf" ; Skapa mappar: Av ]
Ange variabel [ $felkod ; Värde: Get ( SenasteFel ) ]
If [ $felkod = 0 ]
    Visa anpassad dialogruta [ "Klart" ; "PDF-filen har skapats" ]
Else
    Visa anpassad dialogruta [ "Fel" ; "Det gick inte att spara PDF-filen: " & $felkod ]
End If

Relaterade avsnitt