Lägg till i PDF

Lägger till PDF-sidor i den fil som öppnats med scriptsteget Öppna PDF eller skapats med scriptsteget Skapa PDF.

Se även 

Tillval 

  • Från avser hur PDF-filens plats anges:

    • Fil anger en sökväg till PDF-fil. När alternativet är markerat blir alternativet Källfil tillgängligt.

    • Källa anger en PDF-fil i ett containerfält eller i en variabel. När alternativet är markerat blir alternativet Källa tillgängligt.

  • Källfil definierar en lista med en eller flera sökvägar och filnamn för PDF-filen när Från är Fil. Scriptsteget söker igenom listan och använder den första PDF-filen som hittas. Sökvägarna måste använda ett av sökvägsprefixen image. Mer information finns i Skapa filsökvägar.

  • Källa anger det containerfält eller en variabel som lagrar PDF-filen när Från är Källa.

  • Lösenord är ett textuttryck för lösenordet som krävs för att öppna en krypterad PDF-fil. Om PDF-filen inte är krypterad ignoreras det här alternativet.

Kompatibilitet 

Produkt Stöds
FileMaker Pro Ja
FileMaker Go Ja
FileMaker WebDirect Delvis
FileMaker Server Ja
FileMaker Cloud Ja
FileMaker Data API Ja
Anpassad webbpublicering Ja

Ursprungsversion 

26.0

Beskrivning 

Det här scriptsteget lägger till sidor från den PDF-fil som är källa till den PDF-fil som är öppen för tillfället. Du måste först öppna eller skapa en PDF-fil med Scriptsteget Öppna PDF eller Scriptsteget Skapa PDF innan du kan använda det här scriptsteget.

Alla sidor från källfilen läggs till i slutet av den PDF-fil som för närvarande är öppen. PDF-filen som är källa ändras inte med den här åtgärden.

Du kan använda det här scriptsteget för att kombinera flera PDF-dokument i en och samma fil. Du kan till exempel lägga till standardsidor (till exempel omslag, villkor eller bilagor) i genererade rapporter.

Kommentarer 

  • En PDF-fil måste vara öppen innan du kan använda det här scriptsteget. Om ingen PDF-fil är öppen returneras felkod 829 ("Ingen PDF-fil är öppen att lägga till i").

  • Om lösenordet för krypterade PDF-filer saknas eller är felaktigt returnerar det här scriptsteget felkod 831 ("Ogiltigt PDF-lösenord").

  • I FileMaker WebDirect stöds inte alternativet Från: Fil.

Exempel 1 - Skapa en rapport med ett försättsblad

Skapar en ny PDF-fil, lägger till ett standardförsättsblad och sparar hela dokumentet.

Kopiera 
Skapa PDF [ ]
Lägg till i PDF [ Från: Fil ; "Standardförsättsblad.pdf" ]
Stäng PDF [ Spara i: Fil ; "Rapport.pdf" ]

Exempel 2 - Kombinera flera PDF-filer

Går till den första posten i layouten Kontrakt, öppnar en befintlig PDF-fil i Global::KombineradPDF, lägger till PDF-filen som finns i fältet Avtal::AvtalPDF i varje post och stänger och sparar sedan den kombinerade PDF-filen i fältet KombineradPDF igen.

Kopiera 
Gå till layout [ "Kontrak" (Kontrakt) ; Animering: Ingen ]
Gå till post/sökpost/sida [ Första ]

Öppna PDF [ Från: Källa ; Källa: Global::KombineradPDF ]
Loop [ Rensa: Alltid ]
    Lägg till i PDF [ Från: Källa ; Källa: Kontrakt::KontraktPDF ]
    Gå till post/sökpost/sida [ Nästa ; Avbryt efter sista: På ]
End Loop

Stäng PDF [ Spara i: Mål ; Mål: Global::KombineradPDF ]

Exempel 3 - Lägg till i krypterad PDF-fil med lösenordshantering

Skapar en PDF-fil i minnet och frågar sedan användaren efter lösenordet för den krypterade PDF-filen där tillägget ska göras. Om tillägget kan göras läggs den aktuella posten till i PDF-filen som sedan stängs och sparas till en filsökväg. Annars visas ett felmeddelande och PDF-filen rensas från minnet genom att sparas i en lokal variabel, som rensas när scriptet avslutas.

Kopiera 
Manuell felhantering [ På ]
Skapa PDF [ ]

Visa anpassad dialogruta [ "Lösenord för konfidentiell PDF" ; $inmatatLösenord ]

Lägg till i PDF [ Från: Fil ; "KonfidentiellBilaga.pdf" ; Lösenord: •••••••• ]
Ange variabel [ $felkod ; Värde: Get ( SenasteFel ) ]

If [ $felkod ≠ 0 ]
    If [ $felkod = 831 ]
        Visa anpassad dialogruta [ "Autentiseringen misslyckades" ; "Felaktigt lösenord för konfidentiellt dokument." ]
    Else If [ $felkod = 832 ]
        Visa anpassad dialogruta [ "Åtkomst nekas" ; "Säkerhetsinställningarna för PDF-filen förhindrar kopiering." ]
    Else
        Visa anpassad dialogruta [ "Fel" ; "Det gick inte att lägga till dokumentet. Felkod: " & $felkod ]
    End If
    
    Stäng PDF [ Spara i: Mål ; Mål: $ignoreraPDF ]
    Avsluta script [ Textresultat: "Misslyckades" ]
End If

Spara poster i PDF-format [ Återställ ; Spara i: Nu öppen PDF ; Aktuell post ]

Stäng PDF [ Spara i: Fil ; "Ej_konfidentiell_rapport.pdf" ; Skapa mappar: Av ]

Relaterade avsnitt