PDF maken

Hiermee maakt u een leeg PDF-bestand in het geheugen. Voeg pagina's toe met scriptstappen zoals PDF toevoegen, sluit het bestand en sla het op met de scriptstap PDF sluiten.

Zie ook 

Opties 

  • Opties opgeven geeft het dialoogvenster PDF-opties weer. Wanneer deze optie is geselecteerd, geeft Herstellen aan dat PDF-opties zijn opgeslagen in de scriptstap.

    • Op het tabblad Document kunt u beschrijvende informatie voor het PDF-bestand opgeven. Voor elk van de opties op het tabblad Document kunt u rechtstreeks tekst invoeren of op Opgeven klikken om een veldnaam of waarden uit een berekening op te geven.

    • Op het tabblad Beveiliging kunt u wachtwoorden aan het PDF-bestand toewijzen, alsook privileges voor het afdrukken en bewerken. Als u afdruk- en bewerkingsprivileges toestaat, kunt u ook opgeven of kopiëren en schermleessoftware zijn toegestaan.

    • Op het tabblad Beginweergave kunt u de beginweergave voor de lay-out en uitvergroting voor het PDF-bestand definiëren.

Compatibiliteit 

Product Ondersteund
FileMaker Pro Ja
FileMaker Go Ja
FileMaker WebDirect Ja
FileMaker Server Ja
FileMaker Cloud Ja
FileMaker Data API Ja
Custom Web Publishing Ja

Afkomstig uit versie 

26.0

Beschrijving 

Met deze scriptstap wordt een nieuw, leeg PDF-bestand in het geheugen gemaakt dat u vervolgens kunt wijzigen met andere scriptstappen voor PDF-bestanden. Het PDF-bestand is geopend en blijft open totdat u het sluit met de PDF sluiten scriptstap of de PDF annuleren scriptstap.

Nadat een PDF-bestand is geopend, kunt u:

Deze workflow is handig voor het maken van complexe PDF-documenten waarin pagina's uit meerdere bronnen, zoals een voorblad, rapportgegevens en bijlagen, worden gecombineerd in één PDF-bestand.

Opmerkingen 

  • Er kan slechts één PDF-bestand tegelijk worden geopend. Als er al een PDF-bestand is geopend, retourneert deze scriptstap de foutcode 833 ("PDF-bestand is al geopend").

  • Het gemaakte PDF-bestand bestaat alleen in het geheugen totdat u het opslaat met de PDF sluiten scriptstap.

  • Het geopende PDF-bestand en eventuele niet-opgeslagen wijzigingen gaan verloren als een van de volgende situaties zich voordoet:

    • De huidige FileMaker-clientsessie wordt beëindigd

    • Het FileMaker Pro-bestand waarvan het script het PDF-bestand heeft geopend, wordt gesloten zonder het geopende PDF-bestand te sluiten

Voorbeeld 1 - Maak een eenvoudig PDF-document

Hiermee maakt u een PDF-bestand, voegt u pagina's toe voor de records die momenteel worden bekeken en slaat u het bestand op in de map documenten.

Kopiëren 
PDF maken [ ]

Ga naar lay-out [ "Contactpersonen" (Contactpersonen) ; Animatie: Geen ]

Records opslaan als PDF [ Herstellen ; Opslaan in: Momenteel geopende PDF ; Records die worden doorgebladerd ]

Variabele instellen [ $pdfFilePath ; Waarde: Get ( DocumentsPath ) & "Report.pdf" ]

PDF sluiten [ Opslaan in: Bestand ; $pdfFilePath ; Mappen maken: Uit ]

Voorbeeld 2 - Maak een PDF rapport met meerdere secties

Hiermee maakt u een gecodeerd PDF-rapport door een voorblad, meerdere gegevenssecties en een overzichtspagina te combineren. PDF maken gebruikt Specifieke opties om een wachtwoord in te stellen voor het openen van het bestand.

Kopiëren 
PDF maken [ Herstellen ]

PDF toevoegen [ Bron: Bestand ; "CoverPage.pdf" ]

Ga naar lay-out [ "Bestellingen" (Bestellingen) ]
Records opslaan als PDF [ Herstellen ; Opslaan in: Momenteel geopende PDF ; Records die worden doorgebladerd ]

Ga naar lay-out [ "Klanten" (Klanten) ]
Records opslaan als PDF [ Herstellen ; Opslaan in: Momenteel geopende PDF ; Records die worden doorgebladerd ]

PDF toevoegen [ Vanuit: Bron ; Global::SummaryPage ]

Variabele instellen, [ $pdfFilePath ; Waarde: Get ( DocumentsPath ) & "Complete_Report_" & Year ( Get ( CurrentDate ) ) & ".pdf" ]

PDF sluiten [ Opslaan in: Bestand ; $pdfFilePath ; Mappen maken: Uit ]

Voorbeeld 3 - PDF maken met foutafhandeling

Maakt een PDF-rapport met foutafhandeling om ervoor te zorgen dat het PDF-bestand wordt gesloten als er een fout optreedt. Na een mislukte poging om het PDF-bestand te wijzigen, wordt het PDF-bestand gesloten zonder op te slaan door de PDF annuleren scriptstap.

Kopiëren 
Foutafvanging instellen [ Aan ]

PDF maken [ ]
Variabele instellen [ $errorCode ; Waarde: Get ( LastError ) ]
If [ $errorCode ≠ 0 ]
    Aangepast dialoogvenster tonen [ "Fout" ; "Kon geen PDF maken: " & $errorCode ]
    Script afsluiten [ Tekstresultaat: "Mislukt" ]
End If

PDF toevoegen [ Vanuit: Bestand ; "CoverPage.pdf ]
Variabele instellen [ $errorCode ; Waarde: Get ( LastError ) ]
If [ $errorCode ≠ 0 ]
    PDF annuleren
    Aangepast dialoogvenster tonen [ "Fout" ; "Kon geen voorblad toevoegen: " & $errorCode ]
    Script afsluiten [ Tekstresultaat: "Mislukt" ]
End If

Records opslaan als PDF [ Herstellen ; Opslaan in: Momenteel geopende PDF ; Records die worden doorgebladerd ]
Variabele instellen [ $errorCode ; Waarde: Get(LastError) ]
If [ $errorCode ≠ 0 ]
    PDF annuleren
    Aangepast dialoogvenster tonen [ "Fout" ; "Kon geen records toevoegen: " & $errorCode ]
    Script afsluiten [ Tekstresultaat: "Mislukt" ]
End If

PDF sluiten [ Opslaan in: Bestand ; "Report.pdf" ; Mappen maken: Uit ]
Variabele instellen [ $errorCode ; Waarde: Get ( LastError ) ]
If [ $errorCode = 0 ]
    Aangepast dialoogvenster tonen [ "Geslaags" ; "PDF is gemaakt" ]
Else
    Aangepast dialoogvenster tonen [ "Fout" ; "Kon PDF niet opslaan: " & $errorCode ]
End If

Verwante onderwerpen