Criar PDF

Cria um arquivo PDF vazio na memória. Adicione páginas usando etapas de script, como Anexar PDF, feche e salve o arquivo usando a etapa de script Fechar PDF.

Consulte também 

Opções

  • Especificar opções exibe a caixa de diálogo Opções do PDF. Quando esta opção é selecionada, Restaurar indica que as opções do PDF estão armazenadas na etapa de script.

    • Na aba Documento, você pode especificar informações descritivas para o arquivo PDF. Para cada uma das opções na aba Documento, é possível inserir o texto diretamente ou clicar em Especificar para inserir um nome de campo ou valores de um cálculo.

    • Na aba Segurança, você pode atribuir senhas ao arquivo PDF, bem como privilégios de impressão e edição. Se os privilégios de impressão e edição forem permitidos, você poderá especificar se softwares de leitura de tela e cópia serão permitidos.

    • Na aba Exibição inicial, é possível definir a exibição inicial para o layout e a ampliação do arquivo PDF.

Compatibilidade

Produto Compatível
FileMaker Pro Sim
FileMaker Go Sim
FileMaker WebDirect Sim
FileMaker Server Sim
FileMaker Cloud Sim
FileMaker Data API Sim
Publicação na Web personalizada Sim

Originada na versão

26.0

Descrição

Esta etapa de script cria um novo arquivo PDF vazio na memória que você pode modificar usando outras etapas de script de arquivo PDF. O arquivo PDF está aberto e permanece aberto até que você o feche com a etapa de script Etapa de script Fechar PDF ou Etapa de script Cancelar PDF.

Depois que um arquivo PDF é aberto, você pode:

Este fluxo de trabalho é útil para criar documentos PDF complexos que combinam páginas de várias fontes, como uma página de capa, dados de relatório e apêndices, todos reunidos em um único arquivo PDF.

Notas

  • Apenas um arquivo PDF pode ser aberto por vez. Se um arquivo PDF já estiver aberto, esta etapa de script retornará o código de erro 833 ("O arquivo PDF já está aberto").

  • O arquivo PDF criado existe apenas na memória até que você o salve usando a etapa de script Etapa de script Fechar PDF.

  • O arquivo PDF aberto e quaisquer alterações não salvas serão perdidos se um dos seguintes ocorrer:

    • A sessão atual do cliente FileMaker for encerrada

    • O arquivo FileMaker Pro cujo script abriu o arquivo PDF fechar sem fechar o arquivo PDF aberto

Exemplo 1 - Criar um documento PDF simples

Cria um arquivo PDF, adiciona páginas para os registros que estão sendo procurados e o salva na pasta Documentos.

Copiar 
Criar PDF [ ]

Ir para layout [ "Contatos" (Contatos) ; Animação: Nenhum ]

Salvar registros como PDF [ Restaurar ; Salvar em: PDF atualmente aberto ; Registros sendo procurados ]

Definir variável [ $pdfFilePath ; Valor: Get ( DocumentsPath ) & "Report.pdf" ]

Fechar PDF [ Salvar em: Arquivo ; $pdfFilePath ; Criar pastas: Desativado ]

Exemplo 2 - Criar um relatório em PDF com várias seções

Cria um relatório PDF criptografado combinando uma página de capa, várias seções de dados e uma página de resumo. Criar PDF usa Especificar opções para definir uma senha para abrir o arquivo.

Copiar 
Criar PDF [ Restaurar ]

Anexar PDF [ Origem: Arquivo ; "CoverPage.pdf" ]

Ir para layout [ "Pedidos" (Pedidos) ]
Salvar registros como PDF [ Restaurar ; Salvar em: PDF atualmente aberto ; Registros sendo procurados ]

Ir para layout [ "Clientes" (Clientes) ]
Salvar registros como PDF [ Restaurar ; Salvar em: PDF atualmente aberto ; Registros sendo procurados ]

Anexar PDF [ De: Origem ; Global::ResumoPágina ]

Definir variável [ $pdfFilePath ; Valor: Get ( DocumentsPath ) & "Complete_Report_" & Year ( Get ( CurrentDate ) ) & ".pdf" ]

Fechar PDF [ Salvar em: Arquivo ; $pdfFilePath ; Criar pastas: Desativado ]

Exemplo 3 - Criar PDF com tratamento de erros

Cria um relatório em PDF com tratamento de erros para garantir que o arquivo PDF seja fechado se ocorrer um erro. Observe que após uma tentativa fracassada de modificar o arquivo PDF, o ele será fechado sem salvar pela etapa de script Etapa de script Cancelar PDF.

Copiar 
Definir captura de erro [ Ativado ]

Criar PDF [ ]
Definir variável [ $errorCode ; Valor: Get ( LastError ) ]
If [ $errorCode ≠ 0 ]
    Mostrar caixa de diálogo personalizada [ "Erro" ; Não foi possível criar o PDF: " & $errorCode ]
    Sair do script [ Resultado de texto: "Falhou" ]
End If

Anexar PDF [ Do: Arquivo ; "CoverPage.pdf ]
Definir variável [ $errorCode ; Valor: Get ( LastError ) ]
If [ $errorCode ≠ 0 ]
    Cancelar PDF
    Mostrar caixa de diálogo personalizada [ "Erro" ; "Não foi possível adicionar a página de capa: " & $errorCode ]
    Sair do script [ Resultado de texto: "Falhou" ]
End If

Salvar registros como PDF [ Restaurar ; Salvar em: PDF aberto atualmente ; Registros sendo procurados ]
Definir variável [ $errorCode ; Valor: Get(LastError) ]
If [ $errorCode ≠ 0 ]
    Cancelar PDF
    Mostrar caixa de diálogo personalizada [ "Erro" ; "Não foi possível adicionar os registros: " & $errorCode ]
    Sair do script [ Resultado de texto: "Falhou" ]
End If

Fechar PDF [ Salvar em: Arquivo; "Report.pdf" ; Criar pastas: Desativado ]
Definir variável [ $errorCode ; Valor: Get ( LastError ) ]
If [ $errorCode = 0 ]
    Mostrar caixa de diálogo personalizada [ "Sucesso" ; "PDF criado com sucesso" ]
Else
    Mostrar caixa de diálogo personalizada [ "Erro" ; "Não foi possível salvar o PDF: " & $errorCode ]
End If

Tópicos relacionados