Esci dallo script

Interrompe immediatamente lo script, il subscript o lo script esterno in esecuzione.

Opzioni 

Risultato testo specifica un valore di testo da restituire allo script padre. Il valore di solito si basa sullo stato dello script corrente.

Creata nella versione 

6.0 o precedente

Descrizione 

Se utilizzata in un subscript, Esci dallo script ritorna allo script principale con o senza il risultato di uno script opzionale. Se il risultato dello script opzionale viene specificato, questo viene restituito e memorizzato nello script principale fino a che non viene richiamato un altro subscript che restituisce un risultato. Il risultato dello script viene eliminato quando si esce dallo script principale. Il risultato dello script può essere memorizzato in una variabile locale o globale per un successivo impiego.

In certi script eseguiti da alcuni trigger di script è possibile utilizzare questa istruzione di script per restituire Vero o Falso per determinare se è stato elaborato l'evento scatenante. Vedere Trigger di script.

Esempio 1 

Esegue una ricerca e stampa. Se non viene trovato alcun record, visualizza tutti i record ed esce dallo script.

Esegui la ricerca [Ripristina]
If [Get ( ContoTrovati ) = 0]
    Mostra tutti i record
    Esci dallo script [Risultato testo: ]
End If
Stampa [Con finestra di dialogo: Disattivata]

Esempio 2 

Stampa le fatture non pagate. Nel subscript Stampa, gli utenti possono scegliere se stampare le fatture. Se gli utenti scelgono di stamparle, Esci dallo script utilizza il risultato di uno script per inserire "Stampata il <data corrente>" nel campo Stato.

Script principale: Stampa fatture non pagate

Nuova finestra [Stile: Documento; Nome: "Elenco fatture"; Con il formato: "Stampa fatture" (Fatture)]
Esegui la ricerca [Ripristina]
#Richiama il subscript "Stampa" definito di seguito
Esegui script [Specificato: Da elenco; "Stampa"; Parametro: ]
#Continua dopo che il subscript è stato completato
If [Get ( RisultatoScript ) = 1]
    Sostituisci contenuto campo [Con finestra di dialogo: Disattivata; Fatture::Stato; "Stampata il " & Get ( DataCorrente )]
Else
    Mostra tutti i record
    Ordina i record [Ripristina; Con finestra di dialogo: Disattivata]
End If

Subscript: Stampa

Mostra finestra personalizz. ["Stampa fatture non pagate"; "Stampare le fatture non pagate?"]
If [Get ( SceltaUltimoMessaggio ) = 1]
    Stampa [Con finestra di dialogo: Disattivata]
Else
    Chiudi finestra [Finestra corrente]
End If
#Utilizza il parametro Risultato per passare la scelta dell'utente allo script principale
Esci dallo script [Risultato testo: Get ( SceltaUltimoMessaggio )]

Argomenti correlati 

• Funzione Get ( RisultatoScript )
• Istruzione di script Arresta Script
• Istruzioni di script
• Informazioni sulle formule