Crear PDF

Crea un archivo PDF vacío en la memoria. Añada páginas usando pasos de guión como Agregar PDF, luego cierre y guarde el archivo usando el paso de guión Cerrar PDF.

Temas relacionados 

Opciones 

  • Especificar opciones muestra el cuadro de diálogo Opciones de PDF. Cuando se selecciona esta opción, Restaurar indica que las opciones de PDF se almacenan en el paso de guión.

    • En la pestaña Documento, puede especificar información descriptiva para el archivo PDF. En cada una de las opciones de la pestaña del documento, puede introducir texto directamente, o hacer clic en Especificar para introducir un nombre de campo o valores de un cálculo.

    • En la pestaña Seguridad, puede asignar contraseñas al archivo PDF, así como privilegios de impresión y edición. Si se permiten los privilegios de impresión y edición, puede especificar si se permite la copia y el software de lectura en pantalla.

    • En la pestaña Vista inicial, puede definir la vista inicial para la presentación y el aumento para el archivo PDF.

Compatibilidad 

Producto Format
FileMaker Pro Sí
FileMaker Go Sí
FileMaker WebDirect Sí
FileMaker Server Sí
FileMaker Cloud Sí
FileMaker Data API Sí
Publicación en la Web personalizada Sí

Se origina en 

26.0

Descripción 

Este paso de guión crea un nuevo archivo PDF vacío en la memoria que luego puede modificar usando otros pasos de guión de archivos PDF. El archivo PDF está abierto y permanece abierto hasta que lo cierre con el paso de guión Cerrar PDF o el paso de guión Cancelar PDF.

Después de abrir un archivo PDF, puede:

Este flujo de trabajo es útil para crear documentos PDF complejos que combinan páginas de múltiples fuentes, como una portada, datos de informes y anexos, todos ensamblados en un solo archivo PDF.

Notas 

  • Solo se puede abrir un archivo PDF a la vez. Si un archivo PDF ya está abierto, este paso de guión devuelve el código de error 833 ("El archivo PDF ya está abierto").

  • El archivo PDF creado solo existe en la memoria hasta que lo guarde usando el paso de guión Cerrar PDF.

  • El archivo PDF abierto y cualquier cambio no guardado se pierden si ocurre alguna de las siguientes cosas:

    • La sesión actual del cliente de FileMaker finaliza

    • El archivo de FileMaker Pro cuyo guión abrió el archivo PDF se cierra sin cerrar el archivo PDF abierto

Ejemplo 1 - Crear un documento PDF sencillo

Crea un archivo PDF, añade las páginas de los registros que se están consultando en ese momento y lo guarda en la carpeta Documentos.

Copiar 
Crear PDF [ ]

Ir a la presentación [ "Contatos" (Contatos) ; Animación: Ninguna ]

Guardar registros como PDF [ Restaurar ; Guardar en: PDF abierto actualmente ; Registros que se están consultando ]

Establecer variable [ $pdfFilePath ; Valor: Get ( DocumentsPath ) & "Report.pdf" ]

Cerrar PDF [ Guardar en: Archivo ; $pdfFilePath ; Crear carpetas: Inactivo ]

Ejemplo 2 - Crear un informe PDF de varias secciones

Crea un informe PDF cifrado combinando una portada, varias secciones de datos y una página de resumen. Crear PDF utiliza las opciones de Especificar para establecer una contraseña para abrir el archivo.

Copiar 
Crear PDF [ Restaurar ]

Añadir PDF [ Fuente: Archivo ; "CoverPage.pdf" ]

Ir a la presentación [ "Pedidos" (Pedidos) ]
Guardar registros como PDF [ Restaurar ; Guardar en: PDF abierto actualmente ; Registros que se están consultando ]

Ir a la presentación [ "Clientes" (Clientes) ]
Guardar registros como PDF [ Restaurar ; Guardar en: PDF abierto actualmente ; Registros que se están consultando ]

Añadir PDF [ Desde: Origen ; Global::SummaryPage ]

Establecer variable [ $pdfFilePath ; Valor: Get ( DocumentsPath ) & "Complete_Report_" & Año ( Get ( CurrentDate ) ) & ".pdf" ]

Cerrar PDF [ Guardar en: Archivo ; $pdfFilePath ; Crear carpetas: Inactivo ]

Ejemplo 3 - Crear un PDF con gestión de errores

Crea un informe PDF con gestión de errores para garantizar que el archivo PDF se cierre si se produce algún error. Tenga en cuenta que, tras un intento fallido de modificar el archivo PDF, el paso de guión Cancelar PDF cierra el archivo sin guardarlo.

Copiar 
Establecer captura de errores [ Activo ]

Crear PDF [ ]
Establecer variable [ $errorCode ; Valor: Get ( LastError ) ]
If [ $errorCode ≠ 0 ]
    Mostrar cuadro de diálogo personalizado [ "Error" ; "No fue posible crear el PDF: " & $errorCode ]
    Salir del guión [ Resultados de texto: "Error" ]
End If

Añadir PDF [ Desde: Archivo ; "CoverPage.pdf ]
Establecer variable [ $errorCode ; Valor: Get ( LastError ) ]
If [ $errorCode ≠ 0 ]
    Cancel PDF
    Mostrar cuadro de diálogo personalizado [ "Error" ; "No ha sido posible añadir la portada: " & $errorCode ]
    Salir del guión [ Resultados de texto: "Error" ]
End If

Guardar registros como PDF [ Restaurar ; Guardar en: PDF abierto actualmente ; Registros que se están consultando ]
Establecer variable [ $errorCode ; Valor: Get(LastError) ]
If [ $errorCode ≠ 0 ]
    Cancel PDF
    Mostrar cuadro de diálogo personalizado [ "Error" ; "No ha sido posible añadir registros: " & $errorCode ]
    Salir del guión [ Resultados de texto: "Error" ]
End If

Cerrar PDF [ Guardar en: Archivo ; "Report.pdf" ; Crear carpetas: Inactivo ]
Establecer variable [ $errorCode ; Valor: Get ( LastError ) ]
If [ $errorCode = 0 ]
    Mostrar cuadro de diálogo personalizado [ "Success" ; "PDF creado correctamente" ]
Else
    Mostrar cuadro de diálogo personalizado [ "Error" ; "No ha sido posible guardar el PDF: " & $errorCode ]
End If

Temas relacionados