PDF 생성

메모리에 빈 PDF 파일을 생성합니다. PDF 추가와 같은 스크립트 단계를 사용하여 페이지를 추가한 다음, PDF 닫기 스크립트 단계를 사용하여 파일을 닫고 저장하십시오.

다음도 참조하십시오.

스크립트로 작업 자동화하기

옵션

옵션 지정은 PDF 옵션 대화 상자를 표시합니다. 이 옵션을 선택하면 복원은 PDF 옵션이 스크립트 단계에 저장되어 있음을 나타냅니다.
- 문서 탭에서 PDF 파일에 대한 서술적인 정보를 지정할 수 있습니다. 문서 탭의 각 옵션에 대해 텍스트를 직접 입력하거나 지정을 클릭하여 필드 이름이나 계산에서 값을 입력할 수 있습니다.
- 보안 탭에서 프린트 및 편집 권한뿐 아니라 PDF 파일에 암호를 할당할 수 있습니다. 프린트 및 편집 권한이 허용되는 경우 복사 및 화면 판독 소프트웨어가 허용되는지 지정할 수 있습니다.
- 기본 보기 탭에서 레이아웃에 대한 초기 보기와 PDF 파일에 대한 배율을 정의할 수 있습니다.

호환성

제품	지원
FileMaker Pro	예
FileMaker Go	예
FileMaker WebDirect	예
FileMaker Server	예
FileMaker Cloud	예
FileMaker Data API	예
사용자 설정 웹 발행	예

다음 버전에서 시작됨

26.0

설명

이 스크립트 단계는 메모리에 새로운 빈 PDF 파일을 생성하며, 이후 다른 PDF 파일 스크립트 단계를 사용하여 수정할 수 있습니다. PDF 파일은 열려 있으며 PDF 닫기 스크립트 단계 또는 PDF 취소 스크립트 단계로 닫을 때까지 열려 있는 상태를 유지합니다.

PDF 파일을 연 후에는 다음을 수행할 수 있습니다.

PDF 추가 스크립트 단계를 사용하여 콘텐츠를 추가
생성된 레코드를 레코드를 PDF로 저장 스크립트 단계와 "현재 열린 PDF" 옵션을 사용하여 추가
최종 PDF를 PDF 닫기 스크립트 단계를 사용하여 저장

이 워크플로는 표지 페이지, 보고서 데이터 및 부록과 같은 여러 출처의 페이지를 하나의 PDF 파일로 결합하여 복잡한 PDF 문서를 생성하는 데 유용합니다.

참고

한 번에 하나의 PDF 파일만 열 수 있습니다. PDF 파일이 이미 열려 있는 경우, 이 스크립트 단계는 오류 코드 833("PDF 파일이 이미 열려 있습니다..")을 반환합니다.
생성된 PDF 파일은 PDF 닫기 스크립트 단계를 사용하여 저장할 때까지 메모리에만 존재합니다.
다음 중 하나라도 발생하면 열려 있는 PDF 파일과 저장되지 않은 모든 변경 사항이 유실됩니다.
- 현재 FileMaker 클라이언트 세션이 종료
- 스크립트가 PDF 파일을 열었지만, 열려 있는 PDF 파일을 닫지 않은 채 파일이 닫히는 FileMaker Pro 파일

예제 1 - 간단한 PDF 문서를 생성

PDF 파일을 생성하고, 현재 탐색 중인 레코드에 페이지를 추가한 뒤, 문서 폴더에 저장합니다.

복사

PDF 생성 [ ]  

레이아웃으로 이동 [ "Contacts" (Contacts) ; Animation: None ]  

레코드를 PDF로 저장 [ 복원 ; 저장: 현재 열려 있는 PDF ; 탐색 중인 레코드 ]  

변수 설정 [ $pdfFilePath ; Value: Get ( DocumentsPath ) & "Report.pdf" ]  

PDF 닫기 [ 저장: 파일 ; $pdfFilePath ; 폴더 만들기: 끄기 ]

예제 2 - 다중 섹션 PDF 보고서 생성

표지 페이지와 여러 데이터 섹션, 요약 페이지를 결합하여 암호화된 PDF 보고서를 생성합니다. PDF 생성은 옵션 지정을 사용하여 파일을 열기 위한 암호를 설정합니다.

복사

PDF 만들기 [ 복원 ]  

PDF 추가 [ Source: File ; "CoverPage.pdf" ]  

레이아웃으로 이동 [ "Orders" (Orders) ] 
레코드를 PDF로 저장 [ 복원 ; 저장: 현재 열려 있는 PDF ; 탐색 중인 레코드 ]  

레이아웃으로 이동 [ "Customers" (Customers) ] 레코드를 PDF로 저장 [ 복원 ; 저장: 현재 열려 있는 PDF ; 탐색 중인 레코드 ] 

PDF 추가 [ 출처: 출처 ; Global::SummaryPage ]  

변수 설정 [ $pdfFilePath ; 값: Get ( DocumentsPath ) & "Complete_Report_" & Year ( Get ( CurrentDate ) ) & ".pdf" ]  

PDF 닫기 [ 저장: 파일 ; $pdfFilePath ; 폴더 만들기: 끄기 ]

예제 3 - 오류 처리와 함께 PDF 생성

오류가 발생했을 경우 PDF 파일이 닫히도록 오류 처리를 포함한 PDF 보고서를 생성합니다. PDF 파일을 수정하려는 시도가 실패한 경우, PDF 파일이 PDF 취소 스크립트 단계에 의해 저장되지 않은 채 닫힌다는 점에 유의하십시오.

복사

Set Error Capture [ On ]

PDF 만들기 [ ] 
변수 설정 [ $errorCode ; Value: Get ( LastError ) ] 
If [ $errorCode ≠ 0 ] 
사용자 설정 대화 상자 표시 [ "오류" ; "PDF를 생성할 수 없습니다: " & $errorCode ] 
스크립트 종료 [ 텍스트 결과: "실패" ] 
End If

PDF 추가 [ 보낸 사람: 파일 ; "CoverPage.pdf ] 
변수 설정 [ $errorCode ; Value: Get ( LastError ) ] 
If [ $errorCode ≠ 0 ] 
    PDF 취소 
    사용자 설정 대화 상자 표시 [ "오류" ; "표지 페이지를 추가할 수 없습니다: " & $errorCode ] 
    스크립트 종료 [ 텍스트 결과: "실패" ] 
End If

레코드를 PDF로 저장 [ 복원 ; 저장: 현재 열려 있는 PDF ; 
탐색 중인 레코드 ] 
변수 설정 [ $errorCode ; Value: Get(LastError) ] 
If [ $errorCode ≠ 0 ] 
    PDF 취소
    사용자 설정 대화 상자 표시 [ "오류" ; "레코드를 추가할 수 없습니다: " & $errorCode ] 
    스크립트 종료 [ 텍스트 결과: "실패" ] 
End If  

PDF 닫기 [ 저장: 파일 ; "Report.pdf" ; 폴더 만들기: 끄기 ] 
변수 설정 [ $errorCode ; Value: Get ( LastError ) ] 
If [ $errorCode = 0 ] 
    사용자 설정 대화 상자 표시 [ "성공" ; "PDF가 성공적으로 생성되었습니다" ]
Else 
    사용자 설정 대화 상자 표시 [ "오류" ; "PDF를 저장할 수 없습니다: " & $errorCode ] 
End If