Exemplo de ActiveX Automation (Windows)
Private Sub Form_Load()

'----------------------------------------------
' Código de amostra para acessar o FileMaker Pro
' no Visual Basic.
'
' "FileMaker Pro 7.0 Type Library" deve ser marcado
' e estar disponível em Project/References do Visual Basic.
'----------------------------------------------
 
'----------------------------------------------
' Declaração de objetos e inicialização do FileMaker
'----------------------------------------------
 
' Declarar variáveis de objeto
Dim FMApp As FMPro70Lib.Application
Dim FMDocs As FMPro70Lib.Documents
Dim FMActiveDoc As FMPro70Lib.Document
' Inicializar o FileMaker
Set FMApp = CreateObject("FMPRO.Application")
 
' Definir o objeto Documents
Set FMDocs = FMApp.Documents
 
' Tornar o FileMaker visível (ao inicializar por automação,
' O FileMaker permanece oculto por padrão.)
FMApp.Visible = True
 
'----------------------------------------------
' Consulta aos documentos abertos
'----------------------------------------------
 
'Verificar a contagem de documentos abertos
If FMDocs.Count = 0 Then
Debug.Print "Nenhum documento aberto"
Else
Debug.Print "A contagem de documentos abertos é:"; FMDocs.Count
End If
 
'--------------------------------------------------
' Abertura de um banco de dados do FileMaker e execução de um script
'--------------------------------------------------
 
' Nota: Um arquivo do FileMaker "c:\testing.fmp12" deve estar disponível
' com um script chamado "Primeiro script" para o seguinte
' funcionar.
Dim myOpenFile As Object ' nota: pode também pode ser declarado como
FMPro70Lib.Document
 
Set myOpenFile = FMDocs.Open("c:\testing.fmp12", "","")
myOpenFile.DoFMScript ("Primeiro script")
 
'--------------------------------------------------
' Consulta ao documento ativo
'--------------------------------------------------
 
Set FMActiveDoc = FMDocs.Active
 
' Exibir o nome do documento ativo
Debug.Print "O arquivo ativo é "; FMActiveDoc.FullName
 
'--------------------------------------------------
' Enumeração e fechamento de documentos
'--------------------------------------------------
 
Dim TempToc As Object
 
If FMDocs.Count > 0 Then
 
For Each TempDoc In FMDocs
Debug.Print "Prestes a fechar o documento: "; TempDoc.FullName
TempDoc.Close
Set TempDoc = Nothing
Next
End If
'----------------------------------------------
' Limpar e sair
'----------------------------------------------
Set FMDocs = Nothing
Set FMActiveDoc = Nothing
Set myOpenFile = Nothing
 
' Sair do FileMaker e liberar as variáveis
' (Nota: sempre defina a variável de aplicação como Nothing antes de sair.)
FMApp.Quit
Set FMApp = Nothing
End Sub
Tópicos relacionados 
Utilização do FileMaker Pro ActiveX Automation (Windows)
Objetos, métodos e propriedades de ActiveX Automation (Windows)