Esempio di aggiornamento di plug-in

L'esempio di seguito confronta la versione di un plug-in installato con la versione che si trova in un campo Contenitore nel file FileMaker Pro e, se necessario, aggiorna il plug-in.

  1. Nel file dell'app personalizzata, creare una tabella chiamata Aggiorna plug-in in cui salvare le informazioni sul plug-in.
  2. Definire i seguenti campi:

    3. Nome del campo

    Tipo di campo

    Nome plug-in

    Testo

    Versione richiesta del plug-in

    Numero

    Versione installata del plug-in

    Calcolo (non salvato). Per il codice di esempio, vedere Calcolo versione plug-in client di seguito.

    Stato del plug-in installato

    Calcolo (non salvato). Per il codice di esempio, vedere Calcolo stato di abilitazione plug-in client di seguito.

    File del plug-in

    Contenitore
  3. Creare un formato di nome Informazioni di aggiornamento del plug-in e aggiungerlo ai campi definiti nel passo 2.
  4. Creare il seguente script e assegnargli il nome Installa plug-in:
    Copia
    Imposta cattura errori [Attivata] 
    Installa file plug-in [Aggiornamento dei plug-in::File plug-in] 
    # 
    #Gestisci errori
    If [Get ( UltimoErrore ) ≠ 0]
         If [Get ( UltimoErrore ) = 3]
            Mostra finestra personalizz. [Aggiornamento dei plug-in::File plug-in & " non è stato installato. Assicurarsi che Consenti installazione file per soluzioni sia selezionato nelle impostazioni dei plug-in di FileMaker Pro."]
        Else If [Get ( UltimoErrore ) = 1550]
            Mostra finestra personalizz. [Aggiornamento dei plug-in::File plug-in & " è stato installato ma non inizializzato."]
        Else If [Get ( UltimoErrore ) = 1551]
            Mostra finestra personalizz. [Aggiornamento dei plug-in::File plug-in & " non è stato installato."]
        Else
            Mostra finestra personalizz. ["Errore generale " & Get ( UltimoErrore ) & " durante l'installazione " & Aggiornamento dei plug-in::File plug-in]
        End If
    End If
  5. Creare il seguente script e assegnargli il nome Controlla versioni plug-in.
    Copia
    Vai al formato ["Informazioni di aggiornamento del plug-in"]
    Vai a Record/Richiesta/Pagina [Primo]
    Loop [Scarica: Sempre]
        If [Aggiornamento dei plug-in::Versione plug-in installata < Aggiornamento dei plug-in::Versione plug-in richiesta]
            #Il plug-in deve essere installato o aggiornato.
            Esegui script [Specificato: Da elenco; "Installa plug-in";
            Parametro: ]
        End If
        Vai a Record/Richiesta/Pagina [Successivo; Esci dopo l'ultimo: Attivata]
    End Loop
  6. Creare il seguente script e assegnargli il nome Controlla se attivato:
    Copia
    Imposta cattura errori [Attivata] 
    Esegui la ricerca [Ripristina] 
    #Ricerca "Attivato" nel campo di stato del plug-in installato
    If [Get ( ContoTrovati ) < Get ( ContoRecordTotale )] 
        Mostra finestra personalizz. ["Alcuni plug-in richiesti non sono attivati. Assicurarsi che Consenti installazione file per soluzioni sia selezionato nelle impostazioni dei plug-in di FileMaker Pro."]
    End If
  7. Creare uno script all'avviamento Script di Aggiornamento dei plug-in che faccia riferimento agli script di cui sopra nell'ordine quando il database viene aperto:
    Copia
    Esegui script [Specificato: Da elenco; "Controlla versioni plug-in";
    Parametro: ]
    Esegui script [Specificato: Da elenco; "Controlla se attivato";
    Parametro: ]
    Vai al formato [formato originale ; Animazione: Nessuna]

Calcolo versione plug-in client

Copia 
Dichiara (
    [
    PosizioneNomePlug-in = Posizione ( Get ( PluginFMInstallati ) ; Nome plug-in ; 1 ; 1 ) ;
    InizioVersionePlug-in = PosizioneNomePlug-in + Lunghezza ( Nome plug-in ) + 1 ;
    FineVersionePlug-in = Posizione ( Get ( PluginFMInstallati ) ; ";" ; PosizioneNomePlug-in ; 2 ) ;
    LunghezzaVersionePlug-in = FineVersionePlug-in - InizioVersionePlug-in
    ];
    If ( ContaRicorrenze ( Get ( PluginFMInstallati ) ; Nome plug-in ) = 0 ; "" ; Mezzo ( Get ( PluginFMInstallati ) ; InizioVersionePlug-in ; LunghezzaVersionePlug-in) )
)

Calcolo stato di abilitazione plug-in client

Copia 
Dichiara (
    [
    PosizioneNomePlug-in = Posizione ( Get ( PluginFMInstallati ) ; Nome plug-in ; 1 ; 1 ) ;
    InizioStatoPlug-in = Posizione ( Get ( PluginFMInstallati ) ; ";" ; PosizioneNomePlug-in ; 2 ) + 1 ;
    FineStatoPlug-in = If ( Posizione ( Get ( PluginFMInstallati ) ; "¶" ; PosizioneNomePlug-in ; 1 ) > 0; Posizione ( Get ( PluginFMInstallati ) ; "¶" ; PosizioneNomePlug-in ; 1 ) ; Lunghezza ( Get ( PluginFMInstallati ) ) + 1 ) ;
    LunghezzaStatoPlug-in = FineStatoPlug-in - InizioStatoPlug-in
    ];
    If ( ContaRicorrenze ( Get ( PluginFMInstallati ) ; Nome plug-in ) = 0 ;
    "" ; Mezzo ( Get ( PluginFMInstallati ) ; InizioStatoPlug-in ; LunghezzaStatoPlug-in ) )
)

Note 

  • Per installare i plug-in, è necessario selezionare l'opzione Consenti installazione file per soluzioni nelle impostazioni dei plug-in del client. Vedere Modifica delle impostazioni dei plug-in.
  • Se un plug-in è stato disattivato nelle impostazioni dei plug-in del client, viene installato ma non è accessibile finché non viene abilitato manualmente dall'utente.
  • In ogni campo Contenitore si può salvare un unico plug-in, ma è possibile visualizzare tutte le informazioni sui plug-in creando campi Contenitore per più plug-in su un unico formato.

Argomenti correlati