プラグインファイルのインストール

コンピュータにオブジェクトフィールドからプラグインファイルをインストールまたは更新します。

参照 

オプション 

[ターゲットフィールドの指定] では、インストールまたは更新するプラグインのオブジェクトフィールドを指定できます。フィールドが指定されていない場合は、FileMaker Pro ではアクティブなテーブル内の現在のオブジェクトフィールドのプラグインがインストールされます。

互換性 

製品 サポート
FileMaker Pro はい
FileMaker Go いいえ
FileMaker WebDirect はい
FileMaker Server はい
FileMaker Cloud はい
FileMaker Data API はい
カスタム Web 公開 はい

起点バージョン 

12.0

説明 

プラグインのインストールまたは更新の前にオブジェクトフィールド内にプラグインを挿入する必要があります。ファイルを挿入またはプラグインのインストールを参照してください。

インストールできるのは FileMaker プラグインだけです。ターゲット、またはアクティブなオブジェクトフィールドにプラグイン以外のファイルがあるとスクリプトの実行時には何も処理されません。プラグインの拡張子は .fmx64 (Windows)、.fmplugin (macOS)、または .fmx (Linux) です。

ZIP 形式の圧縮されたプラグインファイルや TAR 形式のプラグインファイルはインストールできません。

インストールされているプラグインファイルの名前、バージョン、有効な状態を確認するには、Get (インストールされた FM プラグイン) 関数を使用します。この関数はインストールされているプラグインがソリューションファイルで必要なプラグインよりも新しいか、古いかを判定するのに役立ちます。Get (インストールされた FM プラグイン) または Get (インストールされた FM プラグインの JSON) を参照してください。

プラグインが認識されるためには、プラグインの環境設定でプラグインが有効になっている必要があります。[プラグインファイルのインストール] スクリプトステップがプラグインの更新をインストールしてもプラグインの環境設定でそのプラグインが無効になっている場合は、FileMaker Pro では更新がインストールされてもプラグインは有効になりません。環境設定: プラグインを参照してください。

FileMaker Server で共有されているファイルの場合、サーバー管理者は Admin Console で [プラグインファイルのインストール] スクリプトステップを有効にする必要があります。Claris Server および FileMaker Server ヘルプを参照してください。

メモ 

  • システム管理者は、登録ファイルを使用した複数のコンピュータへのインストール中にプラグインを無効にすることや、FileMaker Pro でプラグインの更新がインストールされないようにすることができます。FileMaker Pro ネットワークインストールセットアップガイドを参照してください。

  • このスクリプトステップは、FileMaker Cloud ホストにより実行されるサーバーサイドスクリプトではサポートされていません。

例 1 

「ビデオ」プラグインをインストールします。

コピー 
カスタムダイアログを表示 ["ビデオプラグインの最新バージョンをインストールしますか?"]
If [Get (最終メッセージ選択) = 1]
    プラグインファイルのインストール [プラグイン::ビデオ]
End If

例 2

このスクリプトを実行するオペレーティングシステムとシステムのハードウェアアーキテクチャに基づいて、適切なオブジェクトフィールドからプラグインをインストールします。

コピー 
変数を設定 [$plugin_json ; 値: Get (インストールされた FM プラグインの JSON)]
変数を設定 [$arch ; 値: JSONGetElement ($plugin_json ; "environment.architecture")]
変数を設定 [$platform ; 値: GetAsNumber (JSONGetElement ($plugin_json ; "environment.platform"))]

# macOS
If [$platform = 1]
    If [$arch = "arm64"]
        # Apple シリコン
        プラグインファイルのインストール [プラグイン::macOS_Universal] 
    Else If [$arch = "x86_64" and IsEmpty (プラグイン::macOS_Universal)]
        # Intel プラグインは利用可。ユニバーサルプラグインは利用不可
        プラグインファイルのインストール [プラグイン::macOS_Intel] 
    Else
        # Intel プラグインとユニバーサルプラグインの両方が利用可
        プラグインファイルのインストール [プラグイン::macOS_Universal] 
    End If
    現在のスクリプト終了 [テキスト結果:"macOS 用のプラグインがインストールされました"] 
End If

# Windows
If [$platform = -2]
    プラグインファイルのインストール [プラグイン::Windows_64bit] 
    現在のスクリプト終了 [テキスト結果:"Windows 用のプラグインがインストールされました"] 
End If

# Linux
If [$platform = 5]
    If [PatternCount (Get (ホストアプリケーションバージョン) ; "Cloud Server 2") > 0]
    Else
        プラグインファイルのインストール [プラグイン::Linux] 
        現在のスクリプト終了 [テキスト結果:"Linux 用のプラグインがインストールされました"] 
    End If
End If

カスタムダイアログを表示 ["このプラットフォームではプラグインがサポートされていません。"]

例 3 

プラグイン更新の例を参照してください。

関連項目